Có thể bạn quan tâm


Đang tải thanh công cụ tìm kiếm ...

Hiện kết quả từ 1 tới 9 của 9

Toàn tập các vấn đề về Unicode trong VB6

Chủ đề được gửi trong chuyên mục Visual Basic 6.0 bởi Vũ Thanh Lai


  1. 23-04-2009, 08:17 PM

    Toàn tập các vấn đề về Unicode trong VB6

    Unicode trong VB6 và MS Access

    Bạn có bao giờ gặp trục trặc với tiếng Việt Unicode trong các ứng dụng Access của mình chưa? Một vấn đề mà nhiều bạn đọc gặp phải trong Access 2000 (chạy trên Win98), khi thực hiện function chuyển số sang chữ (ví dụ: "123" thành "một trăm hai mươi ba")dùng chữ Việt Unicode khi gởi ra form thì không hiển thị được chữ Việt.

    Trước khi giải quyết vấn đề chúng ta cần làm rõ một số điểm. Thường Office 2000 dùng ngôn ngữ VBA version 6.0 để viết code. Trên Win9x hay WinMe, có hai trở ngại khi dùng Unicode trong lập trình hiển thị chuỗi Unicode lên các phần tử giao diện, đó là:

    1. Môi trường soạn thảo code VBA không cho phép bạn nhập đúng các chuỗi Unicode.

    2. Các đối tượng giao diện chuẩn của VBA, version 6.0 không hiển thị được chuỗi Unicode.

    Để khắc phục 2 trở ngại trên, bạn nên:

    1. Nhập chuỗi Unicode trong cửa sổ thiết kế giao diện và cửa sổ soạn code theo định dạng UTF-8 vì định dạng này tương thích với mã ASCII truyền thống. Dĩ nhiên, trước
    khi sử dụng thật chuỗi UTF-8, bạn cần chuyển nó về định dạng USC-2 thông qua việc gọi hàm API Windows có tên là MultibyteToWideChar().

    2. Thay vì dùng các đối tượng giao diện có sẵn của môi trường thiết kế VBA, bạn phải dùng các đối tượng Form2 tương ứng. "Microsoft Form 2.0 Object Library" là một thư viện các đối tượng giao diện mà Microsoft mới viết sau này để hỗ trợ đúng mã Unicode.
    Chúng tôi có viết một form đơn giản, có 1 textbox để nhập giá trị số, 1 textbox để hiển thị chuỗi chữ tương ứng (ở dạng đơn giản nhất, cốt yếu để minh họa việc xử lý chuỗi Unicode), 1 button cho phép chuyển số thành chuỗi. Các đối tượng được dùng đều có trong thư viện "Form 2.0". Qui trình xây dựng ứng dụng này gồm các bước cụ thể sau:

    1. Vì phát biểu Declare của VB không khai báo đúng các hàm API có tham số là chuỗi Unicode nên trước tiên bạn phải xây dựng một thư viện kiểu (type library) chứa hàm MultiByteToWideChar() để dùng trong ứng dụng. Hãy dùng một trình soạn thảo văn bản soạn nội dung đặc tả thư viện TypeLib chứa hàm MultiByteToWideChar() bằng ngôn ngữ ODL như sau (cất nội dung lên file uniutil.odl):


    Code:
    [
     uuid(13C9AF40-856A-101B-B9C2-04021C007002),
     helpstring("WIDE Windows API Type Library")
    ]
    library WideWin32API
    {
     [
       helpstring("KERNEL API Calls"),
       dllname("KERNEL32")
     ]
    module KernelAPI
    {
     [
       helpstring("Convert a UTF8 string to a UCS-2 string."),
       entry("MultiByteToWideChar")
     ]
    long _stdcall MultiByteToWideChar
    (
      [in] long CodePage,
      [in] long dwFlags,
      [in] BSTR lpMultiByteStr,
      [in] long cchMultiByte,
      [in] BSTR lpWideCharStr,
      [in] long cchWideChar
    );
    };
    };
    2. Dịch file ODL trên thành file thư viện kiểu uniutil.tlb bằng tiện ích mktyplib.exe. Để có tiện ích này, bạn có thể cài bộ Visual Studio 6.0, nếu cài ở chế độ Typical, bộ VS sẽ được cài vào thư mục "c:\Program Files\Microsoft Visual Studio". Nếu vậy, để dịch file uniutil.odl ở trên, bạn hãy tạo một cửa sổ DOS Prompt, dùng lệnh cd để chuyển về thư mục chứa file uniutil.odl, rồi nhập tuần tự 2 lệnh sau để dịch nó:
    Code:
    c:\progra~1\micros~3\vc98\bin\vcvars32.bat
    mktyplib /I c:\progra~1\micros~3\vc98\include /win32 /tlb uniutil.tlb uniutil.odl
    Giả sử tên ngắn của thư mục "Program Files" là progra~1, của thư mục "Microsoft Visual Studio" là micros~3.

    3. Chạy VB, tạo 1 project "Standard Exe" để quản lý ứng dụng.

    4. Ấn chuột phải vào chỗ trống trong cửa sổ ToolBox, chọn mục "Components..." để hiển thị cửa sổ "Components", ấn button Controls, duyệt đến mục "Microsoft Forms 2.0 Object Library" và chọn nó để thêm các phần tử giao diện trong thư viện này vào Toolbox của Project VB.

    5. Chọn menu Project.References... để hiển thị cửa sổ References, ấn button Browse rồi duyệt hệ thống file để chọn file uniutil.tlb vừa tạo ở bước 1 để thêm nó vào Project.

    6. Vẽ lần lượt từng phần tử: 1 TextBox có thuộc tính Name=txtSo; 1 Label kết hợp có thuộc tính Caption="Hãy nhập số :"; 1 CommandButton có thuộc tính Caption="Bắt đầu chuyển" và thuộc tính Name=cmdChuyenSo; 1 TextBox nữa có thuộc tính Name=txtChuoi; 1 Label kết hợp có thuộc tính Caption="Chuỗi tương đương :". Lưu ý rằng bạn phải dùng trình hỗ trợ tiếng Việt có khả năng tạo mã UTF-8 (VietKey 2000, GVSBK 2.2,...) và chọn mã này trong việc nhập các chuỗi tiếng Việt trong lúc thiết kế form và viết code. Cũng lưu ý rằng các phần tử cần vẽ là các phần tử của thư viện "Microsoft Forms 2.0 Object Library", chứ không phải là các phần tử VB chuẩn (thường chúng nằm phía dưới cùng trong cửa sổ ToolBox). Sau khi thiết kế xong, form sẽ có dạng sau (chú ý các chuỗi UTF-8 rất khó đọc):



    7. Tạo thủ tục xử lý sự kiện Click chuột cho button cmdChuyenSo rồi vào cửa sổ viết code của form để nhập đoạn chương trình sau:
    Code:
    Option Explicit
    
    'dãy chứa chuỗi UTF8 mi êu tả các ký số
    'mã ký số 0 đến 9 là 48 đến 57
    Dim dayUTF8(48 To 57) As String
    'dãy chứa chuỗi UCS2 miêu tả các ký số
    Dim dayUCS2(48 To 57) As String
    ' Thủ tục khởi động Form
    Private Sub Form_Load()
    
    Dim s As String
    Dim x() As Byte
    Dim ret As Integer
    Dim i As Integer
       dayUTF8(48) = "không"
       dayUTF8(49) = "một"
       dayUTF8(50) = "hai"
       dayUTF8(51) = "ba"
       dayUTF8(52) = "bốn"
       dayUTF8(53) = "năm"
       dayUTF8(54) = "sáu"
       dayUTF8(55) = "bảy"
       dayUTF8(56) = "tám"
       dayUTF8(57) = "chín"
    ' Chuyển caption của button cmdChuyenSo về Unicode
    
    x = StrConv(cmdChuyenSo.Caption, vbFromUnicode)
    ret = MultiByteToWideChar(65001, 0, x, -1, s, 0)
    s = Space(ret)
    ret = MultiByteToWideChar(65001, 0, x, -1, s, ret)
    
    cmdChuyenSo.Caption = s
    ' Chuyển caption của label lblSo về Unicode
    
    x = StrConv(lblSo.Caption, vbFromUnicode)
    ret = MultiByteToWideChar(65001, 0, x, -1, s, 0)
    s = Space(ret)
    ret = MultiByteToWideChar(65001, 0, x, -1, s, ret)
    
    lblSo.Caption = s
    ' Chuyển caption của label lblChuoi về Unicode
    
    x = StrConv(lblChuoi.Caption, vbFromUnicode)
    ret = MultiByteToWideChar(65001, 0, x, -1, s, 0)
    s = Space(ret)
    ret = MultiByteToWideChar(65001, 0, x, -1, s, ret)
    lblChuoi.Caption = s
    ' Chuyển các chuỗi UTF8 miêu tả các ký số về Unicode
    For i = 48 To 57
    x = StrConv(dayUTF8(i), vbFromUnicode)
    ret = MultiByteToWideChar(65001, 0, x, -1, s, 0)
    s = Space(ret)
    ret = MultiByteToWideChar(65001, 0, x, -1, s, ret)
    dayUCS2(i) = Left(s, Len(s) - 1)
    Next i
    End Sub
    'hàm xử lý sự kiện click chuột
    
    Private Sub cmdChuyenSo_Click()
    Dim so() As Byte
    Dim chuoi As String
    Dim i As Integer
       chuoi = ""
       so = StrConv(txtSo.Value, vbFromUnicode)
       For i = 0 To Len(txtSo.Value) - 1
       chuoi = chuoi & dayUCS2(so(i)) & " "
       Next i
       txtChuoi.Value = chuoi
    End Sub
    Khi chạy, form hiển thị như sau (các chuỗi Unicode đều hiển thị đúng):


    Tác giả: Ts.Nguyễn Văn Hiệp
    Facebook: https://www.facebook.com/vuthanhlai
    Facebook, Yahoo, Phone, Email chỉ dành để liên lạc, tán gẫu và giải trí. Không support qua các kênh này anh em nha ^^
  2. Thành viên dưới đây đã cám ơn bài viết này của Vũ Thanh Lai :

    tuanminhcute (08-06-2009)

  3. 23-04-2009, 08:19 PM

    Toàn tập các vấn đề về Unicode trong VB6

    Hoán chuyển Unicode

    VB6 không đuợc thiết kế để hổ trợ Unicode. Do đó khi dùng VB6 làm ngôn ngữ lập trình để làm việc với Unicode ta chạm phải những trở ngại vì giới hạn của nó.
    VB6 gần như không đá động gì đến Unicode. Người ta nói bên trong data type loại String của VB6 thì nó có khả năng chứa Unicode characters, nhưng thế thôi.
    Có một số nhu cầu ta cần phải giải quyết nếu ta muốn dùng VB6 cho Unicode. Ðó là:

    1. Làm sao hiển thị chữ Việt trong Textbox, Listbox .v.v..
    2. Làm sao đọc và viết Text file chứa Unicode chữ Việt
    3. Làm sao xử lý Text String chứa Unicode chữ Việt
    4. Trong giai đoạn giao thời khi các kiểu chữ VNI, VPS, VISCII, TCVN ..v.v. còn thịnh hành, làm sao ta hoán chuyển các encodings ấy ra Unicode.

    Trong bài nầy ta sẽ tìm hiểu cách đáp ứng các nhu cầu trên qua việc viết một program bằng VB6 để hoán chuyển các Text files có kiểu chữ VNI, VPS, VISCII, TCVN ..v.v. ra Unicode và ngược lại, nhân đó biểu diển cách giải quyết tất cả 4 nhu cầu nói trên.

    Trước hết muốn hiển thị Unicode cho chữ Việt ta cần phải dùng Menu command của VB6 IDE để Project | Components Microsoft Forms 2.0 Object Library. Cái ActiveX nầy cho ta những Label, TextBox, Listbox và ComboBox cần thiết để hiển thị chữ Việt trong Unicode.
    Kế đó, để đọc và viết chữ Việt dưới dạng UTF-8 Unicode, ta chứa Unicode text file trong một XML file giữa một cặp tags tên Text (đó cũng là root node) , rồi dùng Microsoft Document Object Model (DOM) để đọc và viết chữ Việt. Bạn nhớ Project | References Microsoft XML, v3.0 và Microsoft Scripting Runtime. Nguyên phần Text là nodeTypedValue của root node của DOM.
    Làm như thế ta tránh phải đọc từng byte rồi tìm cách chuyển data ấy qua Unicode String. Ở đây phải nhấn mạnh là bạn phải vui lòng dùng MSWindowsNT hay MSWindows2000 mới được. Bạn có thể dùng Notepad trong WindowsNTđể edit XML file chứa chữ Việt và lưu trử dưới format UTF-8 như trong hình dưới đây:



    Việc đọc và viết Việt Unicode text file được làm cho dễ dàng ra bằng cách dùng một VB6 Class tên clsUnicodeText như sau:


    Code:
    Dim MyUnicodeText As clsUnicodeText
    Set MyUnicodeText = New clsUnicodeText
    ' Read Unicode Text from file txtFileName and display in TextBox1(0)
    TextBox1(0).Text = MyUnicodeText.ReadUnicode(txtFileName)
    Listing của Class clsUnicodeText như sau:


    Code:
    Option Explicit
    Private mDOMTextFile As DOMDocument  ' Document Object Model
    Private mXMLPath As String  ' XML filename
    Public Function ReadUnicode(TXMLPath)
      ' Đọc Unicode text từ XML file
      Dim objTextFileRoot As IXMLDOMElement
      Set mDOMTextFile = New DOMDocument
      ' Nhớ XML file name để cập nhật sau
      mXMLPath = TXMLPath
      ' Đọc XML file và tạo 1 DOM
      mDOMTextFile.Load mXMLPath
      'Bắt đầu từ root element của XML
      Set objTextFileRoot = mDOMTextFile.documentElement
      ' Trả về root node's text
      ReadUnicode = objTextFileRoot.nodeTypedValue
    End Function
    
     
    Public Sub WriteUnicode(OutText, Optional TXMLPath)
      ' Cập nhật Unicode Text của XML file hoặc viết sang XML file khác
      If IsMissing(TXMLPath) Then
         ' Gán Text để viết ra Root node của DOM
         mDOMTextFile.documentElement.Text = OutText
         ' Cập nhật XML file
         mDOMTextFile.save mXMLPath
      Else
         ' Đọc 1 dummy file để tạo 1 DOM
         ReadUnicode GetLocalDirectory & "Dummy.xml"
         ' Gán Text để viết ra Root node của DOM
         mDOMTextFile.documentElement.Text = OutText
         ' Viết Text và nhận XML file
         mDOMTextFile.save TXMLPath
      End If
    End Sub  
    
    Khi dùng Sub WriteUnicode ta có thể cho nó tên một XML file nếu ta muốn lưu trử Text trong một file khác với input XML file.
    Trong trường hợp đó, Sub WriteUnicode đọc một XML file trống tên Dummy.xml để tạo một DOM.

    Các nguyên âm có dấu của các encodings VPS, VNI, VISCII, TCVN .v.v được chứa trong các ANSI text file như VPSVowles.txt, VNIVowels.txt, VISCIIVowels.txt, TCVNVowels.txt, .v.v..
    Trong khi đó các nguyên âm có dấu của Unicode chữ Việt đuợc chứa trong một XML file và đuợc đọc vào cùng một cách như mọi XML Unicode text files khác. Nó giống như dưới đây:


    Một khi Unicode text đã đuợc đọc vào trong VB6 Text String rồi, nó đuợc dùng y hệt như cho ANSI characters. Ðó là vì bên trong VB6 Unicode characters đuợc chứa đàng hoàng, không cần biết mỗi character cần bao nhiêu bytes. Nói như thế có nghĩa là các Functions Left, Mid, InStr đều có thể đuợc dùng cho Unicode Text String như một ANSI String bình thường.
    Do đó khi hoán chuyển một nguyên âm từ encoding VPS hay VISCII ra Unicode, và ngược lại, ta có thể dùng mối liên hệ từng nguyên âm một (one-to-one correspondence). Hãy xem cái Function StringToString dùng trong công việc hoán chuyển nầy.


    Code:
    Function StringToString(Vowel1, Vowel2) As String
      ' Dịch thẳng one-to-one bản đồ ký tự từ 1 encoding tới dạng khác
      Dim letter As String
      Dim Text1 As String
      Dim Text2 As String
      Dim i, Pos
      ' Dùng Text1 để thi hành 1 litle nhanh hơn TextBox1(0)
      Text1 = TextBox1(0).Text
      ' Làm việc từng ký tự trong string
      For i = 1 To Len(Text1)
         letter = Mid(Text1, i, 1)
         ' Loại bỏ Carriage Return và Line Feed characters nếu có
         If (letter = vbCr) Then
            Text2 = Text2 & vbCr
         ElseIf (letter = vbLf) Then
            Text2 = Text2 & vbLf
         Else
            ' Tìm vị trí ký tự trong vowel list
            Pos = InStr(Vowel1, letter)
            If Pos <= 0 Then
               ' Không tìm thấy bỏ qua map
               Text2 = Text2 & letter
            Else
               ' Tìm thấy hoán chuyển enconding từ vowel list
               Text2 = Text2 & Mid(Vowel2, Pos, 1)
            End If
         End If
      Next
      StringToString = Text2
    End Function
    Program nầy chỉ hoán chuyển từ các encodings ra Unicode và ngược lại, chớ không có hoán chuyển giữa các encodings không phải là Unicode. Nếu bạn thích thì có thể thêm cho program feature đó. Hay nếu làm biếng thì cứ để program y nguyên rồi hoán chuyển hai lần qua trung gian Unicode.
    Các encodings như VNI và VIQR thì dùng 2 hay 3 characters cho một nguyên âm có dấu. Việc hoán chuyển từ Unicode ra VNI hay VIQR thì đơn giản vì ta có thể look-up trực tiếp. Nhưng từ VNI hay VIQR ra Unicode thì ta thực hiện bằng 2 bước. Bước thứ nhất là thay thế tất cả nguyên âm có dấu bằng dòng chữ như |016 cho a^~ của VIQR lấy từ file VIQRVowelMap.txt. Bước thứ hai là lấy ra Vowel thứ 16, tức là ẫ trong danh sách các Unicode Vowels trong file UnicodeVowels.xml như trình bày phía trên.

    Khi hoán chuyển text files có nhiều lúc bạn sẽ thấy một số chữ trong các encodings không đuợc hiển thị đúng, thí dụ như không display chữ ư của TCVN. Ðó là các trục trặc của MSWindows. Bạn cứ kiểm lại kỷ từ kết quả trong ANSI text file, nó không sai đâu. Unicode text thì luôn luôn hiển thị đúng.



    Nháy vào đây để download source code này.
    Tác giả: thầy Lê Đức Hồng
    File Kèm Theo (Bạn chỉ download được 1 file cùng lúc, vui lòng download từng file) File Kèm Theo (Bạn chỉ download được 1 file cùng lúc, vui lòng download từng file)
    Facebook: https://www.facebook.com/vuthanhlai
    Facebook, Yahoo, Phone, Email chỉ dành để liên lạc, tán gẫu và giải trí. Không support qua các kênh này anh em nha ^^
  4. Thành viên dưới đây đã cám ơn bài viết này của Vũ Thanh Lai :

    tuanminhcute (08-06-2009)

  5. 23-04-2009, 08:20 PM

    Toàn tập các vấn đề về Unicode trong VB6

    Các hàm UNICODE thông dụng

    Đổi chữ thường thành chữ hoa:
    Code:
     Function UpperUniChar(Ch) As String
      ' Return the Uppercase for a given vowel or dd
      Dim Pos  ' Position of character in Unicode vowel list
      ' Locate the character in list of Unicode vowels
      Pos = InStr(UVowels, Ch)
      If (Pos > 67) Then
         UpperUniChar = Ch  ' It's already uppercase - leave it alone
      ElseIf (Pos > 0) Then
         ' It's a Lowercase Unicode Vowel - so get the corresponding Uppercase vowel in the list
         UpperUniChar = Mid(UVowels, Pos + 67, 1)
      Else
         ' It's just a normal ANSI character
         UpperUniChar = UCase(Ch)
      End If
    End Function
    Đọc Text UNICODE từ file


    Code:
    Public Function ReadTextFile(FileName) As String
      ' Write a Unicode String to UTF-16LE Text file
      ' Remember to Project | References "Microsoft Scripting Runtime" to support
      ' FileSystemObject & TextStream
      Dim Fs As FileSystemObject
      Dim TS As TextStream
      ' Create a FileSystem Object
      Set Fs = CreateObject("Scripting.FileSystemObject")
      ' Open TextStream for Input.
      ' TriStateTrue means Read Unicode UTF-16LE
      Set TS = Fs.OpenTextFile(FileName, ForReading, False, TristateTrue)
      ReadTextFile = TS.ReadAll  ' Read the whole content of the text file in one stroke
      TS.Close  ' Close the Text Stream
      Set Fs = Nothing  ' Dispose FileSystem Object
    End Function
    Viết UNICODE text ra file


    Code:
    Public Sub WriteTextFile(FileName, StrOutText)
      ' Read a Unicode String from UTF-16LE Text file
      ' Remember to Project | References "Microsoft Scripting Runtime" to support
      ' FileSystemObject & TextStream
      Dim Fs As FileSystemObject
      Dim TS As TextStream
      ' Create a FileSystem Object
      Set Fs = CreateObject("Scripting.FileSystemObject")
      ' Open TextStream for Output, create file if necesssary
      ' TriStateTrue means Write Unicode UTF-16LE
      Set TS = Fs.OpenTextFile(FileName, ForWriting, True, TristateTrue)
      TS.Write StrOutText  ' Write the whole StrOutText string in one stroke
      TS.Close  ' Close the Text Stream
      Set Fs = Nothing  ' Dispose FileSystem Object
    End Sub
    Cách gọn và tiện nhất để đọc và viết UTF-8 text files là dùng một VB6 Class tên clsUnicodeText dựa vào MS DOM (Document Object Model) và XML như sau:


    Code:
    Dim MyUnicodeText As clsUnicodeText
    Set MyUnicodeText = New clsUnicodeText
    ' Read Unicode Text from file txtFileName and display in TextBox1  
    TextBox1.Text = MyUnicodeText.ReadUnicode(txtFileName)
    Listing của Class clsUnicodeText như sau:

    Code:
    Option Explicit
    Private mDOMTextFile As DOMDocument
    Private mXMLPath As String
    Public Function ReadUnicode(TXMLPath)
      Dim objTextFileRoot As IXMLDOMElement
      Set mDOMTextFile = New DOMDocument
      mXMLPath = TXMLPath
      mDOMTextFile.Load mXMLPath
      'start at the root element of the XML
      Set objTextFileRoot = mDOMTextFile.documentElement
      ReadUnicode = objTextFileRoot.nodeTypedValue
    End Function
    
    Public Sub WriteUnicode(OutText, Optional TXMLPath)
      Dim tDOMNode As IXMLDOMElement  ' Temporary Node for DOM
      If IsMissing(TXMLPath) Then
         ' Save the information on the screen by creating a new element and add its children to the DOM object
         mDOMTextFile.documentElement.Text = OutText
         ' Update the XML file
         mDOMTextFile.save mXMLPath
      Else
         Set mDOMTextFile = New DOMDocument
         ' Create a Node called "Text" in DOM
         Set tDOMNode = mDOMTextFile.createElement("Text")
         ' Make it the Root Node
         mDOMTextFile.appendChild tDOMNode
         ' Assign Output Text to Root Node
         mDOMTextFile.documentElement.Text = OutText
         ' Update the XML file
         mDOMTextFile.save TXMLPath
      End If
    End Sub Nguồn: Vovisoft
    Facebook: https://www.facebook.com/vuthanhlai
    Facebook, Yahoo, Phone, Email chỉ dành để liên lạc, tán gẫu và giải trí. Không support qua các kênh này anh em nha ^^
  6. Thành viên dưới đây đã cám ơn bài viết này của Vũ Thanh Lai :

    tuanminhcute (08-06-2009)

  7. 10-11-2010, 11:19 PM

    Toàn tập các vấn đề về Unicode trong VB6

    Mình đã tổng hợp cách sử dụng tiếng Việt Unicode trong VB6 tại đây http://sinhvienit.net/forum/showpos...17&postcount=7
    Các bạn có thể tham khảo & download toàn bộ về (Bao gồm Source )!
    Mình còn hơi mù mờ về cái đọc unicode từ file text... Mà chắc cũng hok cần tới nên hok mò... hjhj
    Nhấn "Cảm ơn" khi đọc được bài viết hữu ích chứng tỏ bạn là người lịch sự!
    Hết mình vì một cộng đồng Sinh Viên IT Việt Nam hùng mạnh!
  8. 25-04-2013, 06:45 PM

    Toàn tập các vấn đề về Unicode trong VB6

    bài của anh Lai cụ thể quá




    l
  9. 25-04-2013, 07:45 PM

    Toàn tập các vấn đề về Unicode trong VB6

    e củng đang tập tành học cái nay mà em không hiểu gi hết ó hjhj
  10. 25-04-2013, 08:27 PM

    Toàn tập các vấn đề về Unicode trong VB6

    bạn nao pro thì hướng dẫn minh tiếp nhé,thanks các bạn
  11. 12-04-2014, 09:47 AM

    Toàn tập các vấn đề về Unicode trong VB6

  12. 12-04-2014, 09:52 AM

    Toàn tập các vấn đề về Unicode trong VB6







    BÁN VÉ XEM SỰ KIỆN THỂ THAO, GIẢI TRÍ, ĐÀO TẠO
    www.vexem.vn

Facebook comment

Thông tin đề tài

Users Browsing this Thread

Hiện đang có 1 người đang xem bài viết này. (0 thành viên và 1 khách)

Visitors found this page by searching for:

unicode trong vb6

code vba loi font tieng nhat

tạo file định dạng unicode vba

kiểm tra chuỗi tiếng việt trong vba

chuyen ma ANSI dang unicode trong vb6

Xử lí file unicode trong vb6tìm hiểu về phần mềm unicodechuyen file sang unicode trong vbunicode vb6vb6 function doc unicod tieng vietvba chuyen du lieu trong texbox thanh chu hoavideo su dung data combo trong vb 6khac phuc loi font chu trong vb6.0cach danh tieng viet tren label cua vb6microsoft forms 2.0 object library in vb6ms form2.0 vb6huong dan doi so thanh chu trong vb6huong dan viet so thanh chu trong vb6UNICODE TRONG VBAcode hỗ trợ gõ dấu tiếng việt trong vbaham doi chu thuong thanh cu hoa trong vb6một số chữ có dấu bị lỗi font trong vba làm sao khắc phụcreport trong VB6.0load am thanh vao vb 6lỗi font trong vb6 khi load dữ liệu lên