Trang chủDiễn đànThư viện TutorialsTin tứcĐăng kýLiên hệ
DANH MỤC

QUẢNG CÁO


THỐNG KÊ
Số bài giảng: 224
Số chuyên mục: 35
Số thành viên: 746967
Đang online: 3182

Trang chủ >> Lập trình phần mềm >> Visual Basic 6.0
Chương 12 - Dùng Đồ Họa (Phần III)

Graphics Methods

Trong khi các Graphical Controls như Shape, Line cho ta vẽ hình lúc thiết kế thì Graphics Methods cho ta vẽ những thứ ấy lúc run-time. Ta cũng có thể chấm từng đóm (pixel) hay copy cả một Picture từ chỗ nầy đến chỗ khác.

Chỉ cần một chút kinh nghiệm bạn có thể làm hoạt họa (animation) hay tạo visual effects tuyệt diệu mà không cần phải đụng đến Windows API (Application Programming Interface) để dùng Function BitBlt.

Method PaintPicture

Method PaintPicture cho phép bạn copy rất nhanh một khối dữ kiện đồ họa, nói nôm na là một khu vực trong một hình graphic trên form, PictureBox hay Printer đến một nơi khác. Thí dụ bạn copy một hình từ chỗ nầy đến chỗ khác trong form, hay từ form/PictureBox ra Printer Object để một chốc sau bạn in nó ra.

Bạn hãy khởi động một dự án VB6 mới và DoubleClick lên PictureBox Icon trong ToolBox để đặt một PictureBox lên form. Đặt tên PictureBox ấy là picGraphic và set property Visible của nó ra False để ta không thấy nó lúc run-time.

Bây giờ load một hình vào property Picture của picGraphic bằng cách Browse một Bitmap file từ cửa sổ Properties. Ở đây ta chọn INTL_NO.BMP từ folder \Program Files\Microsoft Visual Studio\Common\Graphics\Bitmaps\Assorted


Trong chương trình nầy ta muốn hễ khi đè nút trái của Mouse xuống và di chuyển Mouse cursor thì khi cursor đi đến đâu, hình INTL_NO được vẽ đến đó.

Ta sẽ dùng một Flag để đánh dấu nút-trái-của-Mouse-Down, đặt tên là flgMouseDown. Khi nhận được Event MouseDown ta set flgMouseDown thành True, và khi nhận được Event MouseUp ta reset flgMouseDown thành False. Mỗi lần nhận được Event MouseMove thì nếu flgMouseDown là True ta sẽ PaintPicture INTL_NO.

Để xóa background của form, ta thêm một button tên CmdClearForm để chạy graphic method Cls. Dưới đây là liệt kê code mẫu:

' Flag that indicates that the Mouse's left button is depressed
Dim flgMouseDown As Boolean

Private Sub Form_Load()
' Initialise flgMouseDown to False
flgMouseDown = False
End Sub

Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
' Set Flag flgMouseDown
flgMouseDown = True
End Sub

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
' Paint picGraphic if flgMouseDown is True
If flgMouseDown Then
' Paint full-size picGraphic at Mouse cursor location
PaintPicture picGraphic.Picture, X, Y, picGraphic.Width, picGraphic.Height
End If
End Sub

Private Sub Form_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
' Reset Flag flgMouseDown
flgMouseDown = False
End Sub

Private Sub CmdClearForm_Click()
' Clear the form
Cls
End Sub

Lưu ý là bạn phải declare variable flgMouseDown bên ngoài các Subs để mọi Sub đều thấy và có thể dùng nó. Muốn biết thêm chi tiết về cách dùng method PaintPicture, trong VB6 IDE DoubleClick lên chữ PaintPicture trong code editor để highlight chữ ấy rồi bấm nút F1.

Bạn có thể tải về chương trình MouseMove.zip tại đây.

Method PSet

Ta dùng method PSet (đến từ chữ Point Set) để vẽ một pixel lên form. Ta cần cho biết PSet ở đâu và với màu gì, tức là ta cho nó tọa độ X,Y của pixel và một màu tính từ function RGB.

Dưới đây là code để vẽ pixels đủ màu lên form một cách bất chừng (randomly) về vị trí và màu sắc khi user clicks lên form chính:

Private Sub Form_Click() 
Dim i As Integer
' Variables for pixel coordinates
Dim iXCoord As Integer
Dim iYCoord As Integer
' Variable for primary colours
Dim iRed As Integer
Dim iGreen As Integer
Dim iBlue As Integer
' Start the Random number generation
Randomize
' Plot 2000 dots randomly
For i = 1 To 2000
' get a random XCoord.
' Note that Rnd(1) returns a real number between 0 and 1, eg: 0.384
iXCoord = Int(Rnd(1) * ScaleWidth)
' get a random YCoord.
iYCoord = Int(Rnd(1) * ScaleHeight)
' Get a random number between 0 and 254 for each primary colour
iRed = Int(Rnd(1) * 255)
iGreen = Int(Rnd(1) * 255)
iBlue = Int(Rnd(1) * 255)
' Plot the pixel at iXCoord,iYCoord
PSet (iXCoord, iYCoord), RGB(iRed, iGreen, iBlue)
Next
MsgBox ("All done!")
End Sub
Trong thí dụ trên ta dùng method Randomize để generate sẵn trong bộ nhớ các con số real bất chừng từ 0 đến 0.999. Sau đó mỗi lần ta gọi Function Rnd(1) là nó sẽ trả về một con số real lấy bất chừng từ bộ số do method Randomize generated. Do đó, Rnd(1) * ScaleWidth sẽ cho ta một con số real có trị số từ 0 đến ScaleWidth. Muốn đổi con số real đó ra Integer, ta dùng Function Int.

Khi khởi động chương trình và Click lên form ta sẽ có hình giống như dưới đây:
Mách nước: Để xóa một đóm bạn Pset lại tại chỗ ấy một đóm mới có cùng màu với BackColor của form.

Bạn có thể tải về chương trình PSet.zip tại đây.

Method Line

Method Line vẽ một đường thẳng từ một tọa độ nầy đến một tọa độ khác trong màu do ta chỉ định. Với hai methods PSet và Line ta có thể làm được rất nhiều chuyện. Thí dụ muốn cho một vật di động, ta xóa vật ấy bằng cách vẽ lại nó với cùng màu của BackColor của form, rồi vẽ vật ấy ở vị trí mới. Muốn vẽ một đa giác như tam giác hay chữ nhật ta ráp nhiều đường thẳng lại với nhau, đầu của mỗi đường thẳng là cuối của đường thẳng vừa mới được vẽ trước. Muốn sơn Shade bên trong một hình chữ nhật ta dùng PSet..v.v.

Có ba cách để chỉ định tọa độ của hai đầu của một đường thẳng ta muốn vẽ:
  1. Cho biết tọa độ của đầu và cuối đường thẳng:
    thí dụ: Line (50, 100)-(3000, 4000)
    Khi đường nầy được vẽ xong thì vị trí của graphic cursor có tọa độ là vị trí của cuối đường, tức là CurrentX=3000 và CurrentY=4000 trong trường hợp nầy.

  2. Chỉ cho biết tọa độ cuối đường thẳng:
    thí dụ: Line -(3600, 4500), vbMagenta
    Trong trường hợp nầy vị trí của graphic cursor (CurrentX, CurrentY) được lấy làm tọa độ của đầu đường thẳng khi vẽ. Tức là nếu trước khi execute dòng code nầy CurrentX=3000 và CurrentY=4000 thì dòng code tương đương với:
    Line (3000,4000)-(3600,4500), vbMagenta
  3. Dùng chữ Step để nói sự khác biệt từ CurrentX và CurrentY:
    thí dụ: Line Step(400, 600)-Step(800, -500), vbGreen
    Nếu trước khi execute dòng code nầy CurrentX=3600 và CurrentY=4500 thì dòng code tương đương với:
    Line (4000,5100)-(4800,4600), vbGreen
Trong thí dụ dưới đây, một hình tam giác được vẽ bằng hai cách coding khác nhau. Khi chạy program để thử, bạn hãy lần lượt click Triangle METHOD ITriangle METHOD II để thấy cả hai cách vẽ đều y như nhau, chỉ khác màu thôi.

Private Sub CmdTrianI_Click() 
' Drawing a black triangle: METHOD I
Line (700, 500)-(2800, 2400)
Line (2800, 2400)-(1800, 900)
Line (1800, 900)-(700, 500)
End Sub

Private Sub CmdTrianII_Click()
' Drawing a red triangle: METHOD II
' Draw a red line from Location(700, 500) to Location (2800, 24000)
Line (700, 500)-(2800, 2400), vbRed
' Draw a red line from Location(2800,2400) to Location (1800,900)
Line -(1800, 900), vbRed
' Draw a red line from Location(1800,900) to Location (700,500)
Line -(700, 500), vbRed
End Sub
Để vẽ một hình chữ nhật, cách tiện nhất là dùng Step như dưới đây:

Private Sub Rectangle(ByVal X1 As Integer, ByVal Y1 As Integer, ByVal X2 As Integer, ByVal Y2 As Integer) 
' Draw a rectangle
Line (X1, Y1)-(X2, Y1)
Line -(X2, Y2)
Line -(X1, Y2)
Line -(X1, Y1)
End Sub
Ta còn có thể vẽ một hình chữ nhật với bốn góc tròn như sau:

Private Sub RoundCornerRectangle(ByVal X1 As Integer, ByVal Y1 As Integer, ByVal X2 As Integer, ByVal Y2 As Integer) 
Const Delta = 50
' Draw a rectangle with round corner
Line (X1 + Delta, Y1)-(X2 - Delta, Y1)
Line -Step(Delta, Delta)
Line -(X2, Y2 - Delta)
Line -Step(-Delta, Delta)
Line -(X1 + Delta, Y2)
Line -Step(-Delta, -Delta)
Line -(X1, Y1 + Delta)
Line -Step(Delta, -Delta)
End Sub
Ta cũng có thể sơn Shade bên trong hình chữ nhật bằng cách dùng method PSet để chấm các đóm cách nhau chừng 50 pixels như sau:

Private Sub Shade(ByVal X1 As Integer, ByVal Y1 As Integer, ByVal X2 As Integer, ByVal Y2 As Integer) 
' Shade a roundcorner rectangle by plotting dots using method Pset
Const Delta = 50
Dim i As Integer
Dim j As Integer
' Make sure that X1 is less than X2
' Swap values of X1, X2 if X1 > X2
If X2 < X1 Then
Temp = X1
X1 = X2
X2 = Temp
End If
' Make sure that Y1 is less than Y2
' Swap values of Y1, Y2 if Y1 > Y2
If Y2 < Y1 Then
Temp = Y1
Y1 = Y2
Y2 = Temp
End If
' Plotting dots inside the rectangle at 50 pixels apart
For i = X1 + Delta To X2 - Delta Step 50
For j = Y1 + Delta To Y2 - Delta Step 50
PSet (i, j)
Next
Next
End Sub
Muốn Shade đậm hơn, bạn có thể chấm các đóm gần nhau hơn, thí dụ cho cách nhau 30 pixels thay vì 50 pixels. Có một cách khác là tăng trị số của DrawWidth, độ dày của đường vẽ hay đóm.

Bây giờ phối hợp cách vẽ hình chữ nhật với method Shade nói trên và method Print ta có thể viết chữ bên trong một khung màu nhạt như sau:

Private Sub CmdDrawFrame_Click() 
Dim X1 As Integer
Dim Y1 As Integer
Dim X2 As Integer
Dim Y2 As Integer
' Initialise Coordinates of rectangle
X1 = 4200: Y1 = 1000
X2 = 6200: Y2 = 2000
' Draw a roundcorner rectangle
RoundCornerRectangle X1, Y1, X2, Y2
' Shade the rectangle
Shade X1, Y1, X2, Y2
' Position cursor to Print some text
CurrentX = X1 + 50
CurrentY = Y1 + 50
' Define Font Size
Font.Size = 18
' Print the text at cursor location
Print "Hello there!"
End Sub
Khi chạy chương trình nầy và click tất cả các buttons trên form, bạn sẽ có hình dưới đây:
Hãy nhớ set property AutoDraw của form ra True để các graphic chương trình vẽ không bị mất khi user minimises form.

Bạn cũng có thể dùng những kỹ thuật nói trên với Object Printer để in các mẫu giấy điền chi tiết.

Bạn có thể tải về chương trình Lines.zip tại đây.

Method Circle

Ta dùng Method Circle để vẽ hình tròn, hình bầu dục và đường cung, với bên trong trống rỗng hay được sơn đầy bằng một màu ta chỉ định. Ta phải cho biết tọa độ của tâm điểm vòng tròn và bán kính của nó.

Bạn hãy khởi động một dự án VB6 mới, đặt lên form một button với tên frmCircle và caption Circle & Lines. DoubleClick lên button ấy và viết code sau đây:

Private Sub CmdCircleLine_Click() 
' Draw a circle centered at 2000,1500 with radius equal 800
Circle (2000, 1500), 800
' Draw a vertical line from center
Line (2000, 1500)-Step(0, 800)
' Draw a horizontal line from center
Line (2000, 1500)-Step(800, 0)
End Sub
Bây giờ hãy đặt lên form một button khác tên CmdArc và caption Draw Arc. Thay vì vẽ nguyên một vòng tròn, ta sẽ chỉ vẽ một hình vòng cung bằng màu đỏ.

Để chỉ định rằng ta sẽ vẽ từ vị trí nào trên vòng tròn đến vị trí nào khác, thí dụ từ 45độ đến 230độ, ta cần phải đổi degree ra đơn vị Radian bằng cách dùng Function Rads như sau:

Private Function Rads(ByVal Degree As Single) As Single 
' Convert Degrees to Radian
Const PI = 22 / 7
Rads = Degree / 180 * PI
End Function
Vòng cung luôn luôn được vẽ ngược chiều kim đồng hồ. Dưới đây là code để vẽ một đường vòng cung màu đỏ bán kính 800, tâm điểm ở (4000, 2000), từ 45độ đến 230độ:

Private Sub CmdArc_Click() 
Circle (4000, 2000), 800, vbRed, Rads(45), Rads(230)
End Sub
Ta có thể cho sơn bên trong các hình tròn, hay Pie Slices (một phần của hình tròn) bằng cách set FillStyle bằng 0 và chỉ định màu FillColor. Một Pie Slice là một vòng cung đóng kính bởi hai đường thẳng bán kính ở hai đầu. Muốn vẽ một Pie Slice ta đánh thêm dấu trừ ("-") trước hai trị số Radian, tức là dùng -Rads(45), -Rads(230) thay vì Rads(45), Rads(230).

Dưới đây là code vẽ hai Pie Slices, có tâm điểm lệch nhau một tí, đồng thời thêm chú thích 87.5% và 12.5%.

Private Sub CmdPie_Click() 
FillStyle = 0 ' Fill inside any closed shaped
FillColor = vbYellow
' Draw a Pie Slice from 90deg to 45deg in Yellow
Circle (3000, 4000), 800, , -Rads(90), -Rads(45)
' Position the graphic cursor to Print some text
CurrentX = 2800: CurrentY = 4400
Print "87.5%"
FillColor = vbBlue
' Draw a Pie Slice from 45deg to 90deg in Blue
Circle (3050, 3900), 800, , -Rads(45), -Rads(90)
' Position the graphic cursor to Print some text
CurrentX = 3400: CurrentY = 3000
Print "12.5%"
FillStyle = 1 ' No fill
End Sub
Cách dùng cuối cùng của method Circle là để vẽ một hình bầu dục (Elllipse). Vẽ hình bầu dục giống như vẽ một hình tròn nhưng ta cần cho thêm một parameter gọi là Aspect. Aspect là sự liên hệ giữa bán kính vertical và bán kính horizontal. Thí dụ nếu Aspect=2 thì chiều cao của hình bầu dục gấp đôi chiều ngang, ngược lại, nếu Aspect=0.5 thì chiều ngang sẽ gấp đôi chiều cao.

Dưới đây là code ta dùng để vẽ hai hình bầu dục cùng cỡ, một cái màu tím nằm thẳng đứng và một cái màu xanh nằm ngang.

Private Sub CmdEllipse_Click() 
Circle (1400, 3000), 800, vbMagenta, , , 2
Circle (1400, 3000), 800, vbBlue, , , 0.5
End Sub
Nếu bạn khởi động chương trình và click cả bốn buttons bạn sẽ thấy hình sau đây:


Bạn có thể tải về chương trình Circles.zip tại đây.

Property DrawMode

Thông thường khi ta vẽ, trị số default của property DrawMode13- Copy Pen. Có một trị số DrawMode rất thích hợp cho áp dụng hoạt họa là 7- Xor Pen. Muốn xóa một hình vừa vẽ xong ta chỉ cần vẽ lại hình ấy trong DrawMode Xor Pen, không cần biết trước đó background như thế nào, nó sẽ hiện ra trở lại.
Bài mới nhất cùng chuyên mục Xem bài tiếp theo
Dùng Unicode cho Access 2000 (04-09-2009 | 05:43:50 PM)
Một Editor đơn giản cho Unicode (04-09-2009 | 05:42:37 PM)
Dùng VB6 để hoán chuyển Unicode (04-09-2009 | 05:40:09 PM)
Chương 16 - Lập trình với ADO (phần I) (04-09-2009 | 05:25:10 PM)
Chương 15 - Lập trình với kỹ thuật DAO (04-09-2009 | 05:24:53 PM)
 
 
© Copyright 2009 SINHVIENIT.NET, All right reserved
Thư viện bài giảng nghành công nghệ thông tin SinhVienIT.Net  
Xây dựng và phát triển bởi các thành viên SinhVienIT.net
Liên hệ: Admin@SinhVienIT.Net | VuThanhLai@Gmail.Com
Ghi rõ nguồn http://sinhvienit.net khi sao chép bài ở đây.